'************************************************************
'功能:读取配置文件(.ini,.txt格式)的配置项的值,并返回值
'参数:FilePath - 配置文件的完整路径
'   Mark - 配置开始标记
'   Key - 需要获取的配置项名称
'调用方法:Ret = GetConfig("d:\configure.ini","Computer","IP")
'作者:虎肖至尊
'日期:2013-06-20
'************************************************************
Function GetConfig(FilePath,Mark,Key)
 Dim fso, Str_ReadLine
 Set fso = CreateObject("Scripting.FileSystemObject")
 '判断配置文件是否存在
 If fso.FileExists(FilePath) Then
 '初始化配置标记,默认为未找到
 Flag = 0
 '打开配置文件
 Set ConfigFile = fso.opentextfile(FilePath, 1)
 '循环读取文件数据行
 Do
  Str_ReadLine = ConfigFile.ReadLine
  WScript.Echo Str_ReadLine
  '判断读取的数据行是否为空
  If Str_ReadLine <> "" Then
  '判断读取数据行是否为需要查找的配置开始标记
  If LCase(Trim(Str_ReadLine))="[" & Lcase(Mark) & "]" Then
   '找到配置开始标记
   Flag = 1  
   '循环读取当前配置开始标记下的配置项,直到在当前配置标记下找到所需配置项
   '或下一个配置项开始标记出现时退出
   Do
   Str_ReadLine = ConfigFile.ReadLine
   retNum = InStr(Str_ReadLine,"=")
   '检查读取的配置项是否有等号
   If retNum > 0 Then
    '判断获取配置项名称是否为所需的配置项
    If Trim(LCase(Left(Str_ReadLine,retNum-1)))= Trim(LCase(Key)) Then
    '获取配置项等号后的数据
    GetConfig = Trim(Right(Str_ReadLine,Len(Str_ReadLine)-retNum))
    '找到后,退出函数
    Exit Function 
    End If
   End If
   '判断当前是否为下一个配置项开始标记
   If (InStr(Str_ReadLine,"[")>0 And InStr(Str_ReadLine,"]")>0) Then
    '标记当前配置项开始标记为下一个配置
    Flag = 0
    '退出函数
    Exit Function
   End If
   Loop Until (Flag = 0 Or ConfigFile.AtEndOfStream)
  End If
  End If 
 Loop Until ConfigFile.AtEndOfStream
 '关闭文件
 ConfigFile.Close
 Set fso = Nothing
 Else
 '文件未找到,给出提示信息
 MsgBox "配置文件"&"[" & FilePath &"]不存在,请检查路径是否正确."
 End If
End Function

IP = GetConfig("d:\config\environment.ini","Computer2","IP")
Msgbox IP